Métodos de envio do Controle Dundas.Mailer

O código a seguir demonstra como enviar um email usando os métodos QuickSend e SendMail. A diferença entre os dois métodos é que SendMail incorpora toda a funcionalidade do controle, enquanto QuickSend utiliza apenas algumas propriedades do controle. Por favor note que este exemplo envia mensagens com o mínimo de código necessário, então nem toda a funcionalidade do controle é demonstrada. 

 
Enviando um Email pelo método QuickSend
<%
'Muitos métodos do controle lançam uma exception, entao vamos utilizar On Error
On Error Resume Next  
Dim objMailer 'Controle de Email
'Cria uma instancia do controle de Email
Set objMailer = Server.CreateObject("Dundas.Mailer")
'Envia Email
objMailer.QuickSend "MeuEmail@Dominio.com","Para@Dominio.com","Assunto","Mensagem do Email."
'Voce pode testar o sucesso ou falha da operação utilizando o objeto Err do VBScript
'Tira o objeto da memória
Set objMailer = Nothing
%>
 
Enviando um Email pelo método SendMail
<%
'Muitos métodos do controle lançam uma exception, entao vamos utilizar On Error
On Error Resume Next
Dim objMailer 'Controle de Email
'Cria uma instancia do controle de Email
Set objMailer = Server.CreateObject("Dundas.Mailer")
'Seta propriedades e itens de coleção do controle
objMailer.TOs.Add "ParaAlguem@Dominio.com"
objMailer.FromAddress = "MeuEmail@Dominio.com"
objMailer.Subject = "Assunto"
objMailer.Body = "Mensagem do Email."
'Envia Email
objMailer.SendMail
'Voce pode testar o sucesso ou falha da operação utilizando o objeto Err do VBScript
'Tira o objeto da memória
Set objMailer = Nothing
%>

Enviando um Email em HTML

O básico para enviar Emails em HTML com o Dundas.Mailer é que você não vai mais utilizar a propriedade Body e sim HtmlBody. 

<%
Dim objEmail     'Controle de Email

'Muitos métodos do controle lançam uma exception, entao vamos utilizar On Error
On Error Resume Next
Set objEmail = Server.CreateObject("Dundas.Mailer")     'Objeto de Email
'Endereço de quem vai RECEBER o Email
objEmail.TOs.Add "ParaAlguem@Dominio.com"
'Assunto da Mensagem
objEmail.Subject = "Este é o Assunto."
'Endereço de quem está ENVIANDO o Email
objEmail.FromAddress = "MeuEmail@MeuDominio.com"
'Servidor de SMTP. Aumenta a velocidade de envio
objEmail.SMTPRelayServers.Add "smtp.netwizard.com.br"
'Seta a propriedade HTMLBody. Mensagem do Email em código HTML
objEmail.HTMLBody = "<Html><Head></Head><Body>Mensagem em HTML.</Body></Html>"
'Envia o Email
objEmail.SendMail
'Testa por sucesso ou falha no envio
If Err.Number <> 0 Then
'Ocorreu um erro, então mostramos a descrição
    Response.Write "Desculpe, ocorreu o seguinte erro: " & Err.Description
Else
'Sucesso!
    Response.Write "O Email em HTML foi enviado com sucesso!"
End If
'Tira o objeto da memória
Set objEmail = Nothing
%>

Enviando um Email usando formulário

Para enviar um Email com formulário HTML você deve ter um arquivo contendo o formulário e outro contendo o código ASP. 

Código do arquivo formulario.html

<html>
<head><titulo>Formulário</titulo></head>
<body>
Preencha os campos solicitados:
<br><br>
<form method="post" action="enviar.asp">
Nome:<br><input type="text" name="nome"><br>
Email:<br><input type="text" name="email"><br>
Assunto:<br><input type="text" name="assunto"><br>
Mensagem:<br><textarea name="mensagem" cols="30" rows="5"></textarea><br><br>
<input type="submit" value="Enviar">
</form>
</body>
</html>
 
Código do arquivo enviar.asp
<%
Dim objEmail     'Controle de Email

'Muitos métodos do controle lançam uma exception, entao vamos utilizar On Error
On Error Resume Next
Set objEmail = Server.CreateObject("Dundas.Mailer")     'Objeto de Email

'Vamos capturar os dados passados pelo formulário
Nome = Request("nome")
Email = Request("email")
Assunto = Request("assunto")
Mensagem = Request("mensagem")
'Endereço de quem vai RECEBER o Email
objEmail.TOs.Add "MeuEmail@MeuDominio.com"
'Assunto da Mensagem
objEmail.Subject = Assunto
'Endereço de quem está ENVIANDO o Email
objEmail.FromAddress = Email
'Servidor de SMTP. Aumenta a velocidade de envio
objEmail.SMTPRelayServers.Add "smtp.netwizard.com.br"
'Seta a propriedade Body. Mensagem do Email
objEmail.Body = Mensagem
'Envia o Email
objEmail.SendMail
'Testa por sucesso ou falha no envio
If Err.Number <> 0 Then
'Ocorreu um erro, então mostramos a descrição
    Response.Write "Desculpe, ocorreu o seguinte erro: " & Err.Description
Else
'Sucesso!
    Response.Write "O Email foi enviado com sucesso!"
End If
'Tira o objeto da memória
Set objEmail = Nothing
%>
 
Dúvidas: